6. Multiple regression - PROC GLM

Transcription

1 Use of SAS - November Multiple regression - PROC GLM Karl Bang Christensen Department of Biostatistics, University of Copenhagen. kach@biostat.ku.dk, tel:

2 Contents Analysis of covariance (ANCOVA): the general linear model Interaction Multiple regression Automatic variable selection 2

3 Data example: lung capacity Data from 32 patients subject to a heart/lung transplantation. TLC (Total Lung Capacity) is determined from whole-body plethysmography. Are men and women different with respect to total lung capacity? OBS SEX AGE HEIGHT TLC 1 F F M F M M M

4 Box plots for comparison of sex groups PROC GPLOT DATA=TLCdata; PLOT tlc*sex / HAXIS=AXIS1 VAXIS=AXIS2; AXIS1 LABEL=(H=3) VALUE=(H=2) OFFSET=(6,6)CM; AXIS2 LABEL=(H=3 A=90) VALUE=(H=2); SYMBOL1 V=CIRCLE H=2 I=BOX10TJ W=3; RUN; QUIT; 4

5 Box plots for comparison of sex groups 5

6 Group comparisons Using t-tests PROC TTEST DATA=tlc; CLASS sex; VAR tlc height; RUN; Note: we can specify more than one variable in the VAR statement 6

7 Output T-Tests Variable Method Variances DF t Value Pr > t TLC Pooled Equal TLC Satterthwaite Unequal Height Pooled Equal Height Satterthwaite Unequal Equality of Variances Variable Method Num DF Den DF F Value Pr > F TLC Folded F Height Folded F Obvious sex difference for TLC as well as for Height 7

8 Confounding when comparing groups Occurs if the distributions of some other relevant explanatory variables differ between the groups. Here relevant means things we would have liked to be the same (or at least very similar) for everybody, because we think of it as noise or distortion. Can be reduced by performing a regression analysis with the relevant variables as covariates. Confounding could be a problem in the current example, if we intended to compare the lung function between men and women of similar height 8

9 Relation between tlc and height: PROC GPLOT DATA=TLCdata; PLOT tlc*height=sex / HAXIS=AXIS1 VAXIS=AXIS2; AXIS1 LABEL=(H=4) VALUE=(H=3) MINOR=NONE; AXIS2 LABEL=(A=90 H=4) VALUE=(H=3) ORDER=(3 TO 10) MINOR=NONE; SYMBOL1 C=RED V=DOT H=2 I=SM75S L=1 W=3 MODE=INCLUDE; SYMBOL2 C=BLUE V=CIRCLE H=2 I=SM75S L=41 W=3 MODE=INCLUDE; LEGEND1 LABEL=(H=2.5) VALUE=(H=2 JUSTIFY=LEFT); RUN; QUIT; 9

10 Relation between tlc and height: (Plotted using I=RL) 10

11 Analysis of covariance Comparison of parallel regression lines Model: y gi = α g + βx gi + ε gi g = 1, 2; i = 1,, n g Here α 2 α 1 is the expected difference in the response between the two groups for fixed value of the covariate, that is, when comparing any two subjects who have the same value of (match on) the covariate x ( adjusted for x ). 11

12 But what if the lines are not parallel? More general model: y gi = α g + β g x gi + ε gi If β 1 β 2 there is an interaction between Height and Sex 12

13 Interaction Interaction between Height and Sex The effect of height depends on sex The difference between men and women depends on height 13

14 Model with interaction Group variables PROC REG only works for linear covariates. Group variables can be handled directly in PROC GLM by specifying the group variable as a CLASS variable. SAS code PROC GLM DATA=TLCdata; CLASS sex; MODEL tlc=sex height sex*height / SOLUTION; RUN; QUIT; The option SOLUTION is needed if we want to see the regression parameter estimates. 14

15 Output The GLM Procedure Class Level Information Class Levels Values Sex 2 F M Number of Observations Read 32 Number of Observations Used 32 Dependent Variable: TLC Sum of Source DF Squares Mean Square F Value Pr > F Model <.0001 Error Corrected Total R-Square Coeff Var Root MSE TLC Mean

16 Output II Source DF Type I SS Mean Square F Value Pr > F Sex Height Height*Sex Source DF Type III SS Mean Square F Value Pr > F Sex Height Height*Sex The interaction is not significant. The Type III p-values for the two main effects should never be used for anything in a model including the interaction! 16

17 Output III Standard Parameter Estimate Error t Value Pr > t Intercept B Sex F B Sex M B... Height B Height*Sex F B Height*Sex M B... NOTE: The X X matrix has been found to be singular, and a generalized inverse was used to solve the normal equations. Terms whose estimates are followed by the letter B are not uniquely estimable. These are the regression parameters 17

18 Where are the two lines in the output? Line for males (the reference group): TLC = Height Line for females: TLC = ( 1.727) + ( ) Height = Height 18

19 Same model, new parameterization PROC GLM DATA=TLCdata; CLASS sex; MODEL tlc=sex sex*height / NOINT SOLUTION; RUN; QUIT; Output... Standard Parameter Estimate Error t Value Pr > t Sex F Sex M Height*Sex F Height*Sex M

20 Same model, but with two different parameterizations PROC GLM DATA=TLCdata; CLASS sex; MODEL tlc=sex height sex*height / SOLUTION; RUN; QUIT; The (extrapolated) level at Height=0 for the reference group (Sex= M ) The (extrapolated) difference between the two sexes at Height=0 An effect of Height (slope) for the reference group The difference between the slopes for the two sexes PROC GLM DATA=TLCdata; CLASS sex; MODEL tlc=sex sex*height / NOINT SOLUTION; RUN; QUIT; The (extrapolated) level at Height=0 for each group (Sex) The effect of Height (slope) for each group (Sex) 20

21 Model without interaction No indication of interaction, we omit the term PROC GLM DATA=TLCdata; CLASS sex; MODEL tlc=sex height / SOLUTION CLPARM; RUN; QUIT; Are there also other possible parameterizations in this model? (and which one should we use?) 21

22 Source DF Type I SS Mean Square F Value Pr > F Sex Height Source DF Type III SS Mean Square F Value Pr > F Sex Height Note: The effect of sex seen in the group comparison has disappeared!! 22

23 Model without interaction - results Standard Parameter Estimate Error t Value Pr > t Intercept B Sex F B Sex M B... Height Parameter 95% Confidence Limits Intercept Sex F Sex M.. Height

24 Confounding? In this example it seems that 1. The observed difference in lung capacity between men and women can be explained by height differences 2. However, there may still be a sex difference for persons of the same height (women vs. men), estimated as 0.77 ± = ( 1.78, 0.24) 24

25 But... what if we had not had the two very small men to pull the line for the men? Let us look at the subjects above 152 cm (using the statement WHERE height>152; when running PROC GLM): Test of interaction: Source DF Type I SS Mean Square F Value Pr > F Sex Height Height*Sex Estimated additive effects: Parameter Estimate 95% Confidence Limits Pr > t Intercept B Sex F B Sex M B... Height A somewhat different conclusion... 25

26 Plots for model checking in the HTML output: ODS GRAPHICS ON; PROC GLM DATA=TLCdata PLOTS=(DIAGNOSTICS RESIDUALS(SMOOTH)); CLASS sex; MODEL tlc=sex height sex*height / SOLUTION; OUTPUT OUT=WithResid RSTUDENT=NormResidWithoutCurrent; RUN; QUIT; PROC GPLOT DATA=WithResid; PLOT NormResidWithoutCurrent * sex; SYMBOL1 V=CIRCLE H=2 I=BOX10TJ W=3; RUN; QUIT; In addition to the ODS GRAPHICS plots for PROC GLM, residuals should be plotted against each of the CLASS variables (here sex) in order to check the variance homogeneity across the different values of each CLASS variable. 26

27 Exercise: Another look the Juul data. 1. Get the data into SAS using a libname statement. 2. Create a new data set including only individuals above 25 years, and make a new variable with log-transformed SIGF-I. 3. Use PROC GPLOT to plot the relationship between age and log-transformed SIGF-I. 4. Make separate regression lines for men and women. 5. Do a regression analysis to explore if slopes are equal in men and women. 6. Give an estimate for the difference in slopes, with 95% confidence interval. 27

28 Multiple regression. General linear model (GLM). Data: n sets of observations, made on the same unit : unit x 1...x p y 1 x 11...x 1p y 1 2 x 21...x 2p y 2 3 x 31...x 3p y n x n1...x np y n The linear regression model with p explanatory variables (covariates) is written: y = β 0 + β 1 x β p x p + ε 28

29 Interpretation of regression coefficients Model Y i = β 0 + β 1 X i1 + β 2 X i β p X ip + ɛ where ɛ N(0, σ 2 ). Consider two subjects: A has covariate values (X 1, X 2,..., X p ) B has covariate values (X 1 + 1, X 2,..., X p ) Expected difference in the response (B A) [β 0 +β 1 (X 1 +1)+β 2 X i2 +...] [β 0 +β 1 X 1 +β 2 X i2 +...] = β 1 This means that β 1 is the effect of one unit s difference in X 1 for fixed levels of the other variables (X 2,..., X p ) 29

30 Example: School-age obesity score versus height and weight measured at 1 year of age Obs Obesity Height1 Weight

31 Example: School-age obesity score versus height and weight measured at 1 year of age 31

32 SAS code PROC REG DATA=SchoolObesity; MODEL Obesity = Height1 Weight1 / CLB; RUN; QUIT; (part of the) output Parameter Estimates Parameter Standard Variable DF Estimate Error t Value Pr > t Intercept Height Weight <.0001 Parameter Estimates Variable DF 95% Confidence Limits Intercept Height Weight

33 Interpretation of regression parameters Remember that β j is the effect of the j th explanatory variable, corrected for the effect of the other explanatory variables, that is, when comparing any two subject who match on all the other variables. The effect of Height1 corrected for the effect of Weight1 is found to be ˆβ 1 = (95% CI: to 0.024), p = In the univariate model without correction for Weight1, we got ˆβ 1 = (95% CI: to ), p =

34 Interpretation of regression parameters II The parameter for height answers two different questions depending on whether or not adjusted for weight: Unadjusted: The question is Are big 1-year-old children generally fatter during school age? The answer is yes! Adjusted: The question is Are slim 1-year-old children generally slimmer during school age? The answer is yes! Both questions are relevant and both answers are valid! 34

35 Relative effects and Products or ratios of covariates Both issues are solved by log-transforming the covariate(s)! Example: BMI = Weight/Height 2 is a ratio measure. Logarithmic rules give log(bmi) = log(weight) 2 log(height), so β log(bmi) = β log(weight) 2β log(height) Choice of log-transformation of covariates Use of log 10 means that the regression parameter shows the effect of two subjects differing by a factor 10. Do not use log 10 unless it is likely for two subjects to differ by a factor 10! Use log 2 [SAS code: LOG2( )] when doubling is likely. Use a covariate calculated as XX=LOG( )/LOG(1.1) if 10% differences are more likely. 35

36 Is BMI at age 1 year an appropriate predictor for school-age obesity? 1. BMI is a ratio measure involving weight and height, so we should investigate log-transformed weight and height 2. Doubling is not a realistic difference, so we look at per 10% DATA School1; SET SchoolObesity; HeightPer10pct = LOG(Height1)/LOG(1.1); WeightPer10pct = LOG(Weight1)/LOG(1.1); RUN; PROC REG DATA=School1; MODEL Obesity = HeightPer10pct WeightPer10pct / CLB; TestBMI: TEST HeightPer10pct = -2*WeightPer10pct; RUN; QUIT; 36

37 Part of output: Parameter Estimates Parameter Standard Variable DF Estimate Error t Value Pr > t 95% Conf. Limits Intercept HeightPer10pct WeightPer10pct < Test TestBMI Results for Dependent Variable Obesity Mean Source DF Square F Value Pr > F Numerator <.0001 Denominator

38 Conclusion: 1. A 10% higher weight increases the expected school-age obesity score by (95% CI: ), and a 10% lower height increases the expected school-age obesity score by (95% CI: ), 2. BMI at age 1 year is not an appropriate choice (p < ). However, since the regression parameters for the log-transformed weight and height are of the same size, but with opposite signs, an appropriate predictor would be the ratio weight/height! 38

39 Model selection Lung function - 25 patients with cystic fibrosis O Neill et al (1983). 39

40 Which covariates have a univariate effect on the outcome P E max? Are these the variables to be included in the model? 40

41 Model with all covariates PROC REG DATA=pemax; MODEL pemax=age sex height weight bmp fev1 rv frc tlc; RUN; QUIT; Parameter Standard Variable DF Estimate Error t Value Pr > t Intercept age sex height weight bmp fev rv frc tlc No significant effects... 41

42 Automatic variable selection: Forward selection Start with no covariates. In every step, add the most significant variable PROC REG DATA=pemax; MODEL pemax=age sex height weight bmp fev1 rv frc tlc / SELECTION=FORWARD; RUN; QUIT; Final model: Weight BMP FEV1 42

43 Automatic variable selection: Backward elimination Start with all covariates. At each step, omit the least significant variable PROC REG DATA=pemax; MODEL pemax=age sex height weight bmp fev1 rv frc tlc / SELECTION=BACKWARD; RUN; QUIT; Final model: Weight BMP FEV1 43

44 But... There is no guarantee that these automatic methods will give us the same result: Had observation no. 25 not been in the data set, backward elimination would have excluded Height as the first variable, while forward selection would have included Height as the first variable! A best automatic method has not been identified, but backward elimination is often recommended over forward selection. WARNING: Output from selected model does not take model selection uncertainty into account: The output (regression coefficients and p-values) is identical to what would have been obtained had we fitted the final model with out doing any model selection. The importance of the selected covariates is over-estimated! 44